Puppet Class: isp3node::php::setup

Defined in:
manifests/php/setup.pp

Summary

Install and configure PHP on the host

Overview

Install PHP with a given set of packages, extensions, features and system settings

Examples:

include isp3node::php::setup

Parameters:

  • version (String) —

    PHP Version to install and manage

  • set (Optional[String]) (defaults to: undef) —

    The configuration set to manage on this host

  • sets (Hash[String, Struct[{ Optional[packages] => Array[String], Optional[extensions] => Hash[String, Hash], Optional[features] => Array[Enum['fpm', 'dev', 'composer', 'pear', 'phpunit']], Optional[settings] => Hash[String, Any] }]]) —

    Config sets defining system packages, extensions and features managed on all isp nodes and on special ones like webserver



14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
 
# File 'manifests/php/setup.pp', line 14

class isp3node::php::setup(
  String $version,
  Hash[String, Struct[{
    Optional[packages]   => Array[String],
    Optional[extensions] => Hash[String, Hash],
    Optional[features]   => Array[Enum['fpm', 'dev', 'composer', 'pear', 'phpunit']],
    Optional[settings]   => Hash[String, Any]
  }]] $sets,
  Optional[String] $set = undef,
) {
  unless ($set =~ Undef or has_key($sets, $set)) {
    fail("PHP setup set ${set} is not defined")
  }
  # TODO maybe additional versions from sury, like so:
  # https://github.com/codingfuture/puppet-cfweb/search?q=php&unscoped_q=php

  $my_set = $set ? {
    undef => $sets['default'],
    default => deep_merge($sets['default'], $sets[$set]),
  }
  $my_features = pick($my_set['features'], [])

  ensure_packages($my_set['packages'], {ensure => latest})

  class { '::php::globals':
    php_version => $version,
    config_root => "/etc/php/${version}",
  }
  -> class { '::php':
    ensure       => latest,
    manage_repos => true,
    fpm          => member($my_features, 'fpm'),
    dev          => member($my_features, 'dev'),
    composer     => member($my_features, 'composer'),
    pear         => member($my_features, 'pear'),
    phpunit      => member($my_features, 'phpunit'),
    settings     => $my_set['settings'],
    extensions   => $my_set['extensions'],
  }
}